pro create_combi_model_oh

;IDL procedure for creating a Combi & Delsemme OH model
;and then convolving it with the STIS PSF for comparison with observations.

;Here's the raw output from the model.

read_file,'combi_borrelly_raw_oh.dat',rho,nh2o,noh,boh,skip=17

;Create a denser grid.

delta = 1.478	;geocentric distance

pixel = 0.0244 * 725. * delta	;km/pixel

nrho = findgen(550) * pixel
xpix = findgen(550)
nrho[0] = 0.298 * pixel
nboh = interpol(boh,rho,nrho)

file_xyz,ofile='combi_borrelly_interpol_oh.dat',nrho,nboh,/nonint

;Create 2-dim version of the OH profile.

haser_image,xpix,nboh,ohimage
writefits,'combi_borrelly_ohimage.fits',ohimage

;Get the STIS PSF.

;psf = readfits('/data2/encke/psf/stis/strong_psf.fits')
psf = readfits('/data2/encke/psf/stis/robinson_nuv.fits')
cohimage = convol(ohimage,psf)
writefits,'combi_borrelly_cohimage.fits',cohimage

;After experimenting, I found that just using a single row cutting through
;the brightest pixel should be a good enough. Since running the annuli
;routine is such a cpu-hog, this saves a lot of time in running this routine.

;annuli,cohimage,549,549,1,r,i
i = cohimage[549:*,549]
r = findgen(n_elements(i))
r[0] = 0.298
r = r * pixel
file_xyz,ofile='combi_borrelly_coh.dat',r,i,/nonint
ni = interpol(i,r,nrho)
file_xyz,ofile='combi_borrelly_coh_interpol.dat',nrho,ni,/nonint

return
end